#include <SD.h>
#include <SPI.h>
String logPrefix = "DATEN_";  // Prefix für die Logdateien
String logFileName;           // Name der Datei zum abspeichern der Daten

unsigned long intervall = 1000UL * 5;  // Abstand in dem Werte auf die SD-Karte
                                       // geschrieben werden in Millisekunden

void setup() {
  // Starte die Serielle Schnittstelle
  Serial.begin(9600);

  // Warte solange bis eine SD-Karte eingesteckt wurde
  while (!SD.begin(SS_PIN)) {
    Serial.println("Konnte keine Verbindung zur SD-Karte aufbauen.");
    Serial.println("Versuche es in 2 Sekunden nochmal");
    delay(2000);
  }
  // Finde Dateinamen der frei ist.
  int number = 0;
  while (SD.exists(logPrefix + number + ".CSV")) {
    number++;
  }
  logFileName = logPrefix + number + ".CSV";  // Setze den Namen zusammen
  Serial.println("Setup erfolgreich. Speichere Daten in: " + logFileName);
}
unsigned long lastTime = 0;  // Letzter Zeitpunkt wo die Werte ausgegeben wurden

void loop() {
  unsigned long currentTime = millis();  // Hole die jetzige Zeit.

  // Teste ob die Zeit schon ein Intervall weiter ist.
  if (currentTime - lastTime >= intervall) {
    lastTime = currentTime;  // Aktualisiere den Zeitpunkt

    // sensorValue wird hier beispielsweise mit 42 belegt.
    // Dies ersetzen um richtige Werte abzuspeichern.
    int sensorValue = 42;

    File logFile = SD.open(logFileName, FILE_WRITE);  // Oefffne Datei

    if (!logFile) {
      Serial.println("Konnte die Datei nicht öffnen");
    }

    // Gebe die Daten aus auf der seriellen Schnittselle
    Serial.println(sensorValue);

    // Schreibe die Daten wie folgt auf die SD-Karte "Zeit,sensorValue"
    logFile.print(currentTime);
    logFile.print(",");
    logFile.println(sensorValue);

    logFile.close();  // Schliesse die Datei
  }
}