int ACS_PIN = A0;  // PIN an dem der ACS712 angeschlossen ist

// Solange kein Strom am Sensor fließt, gibt der Sensor eine Spannung von
// circa 2.49 Volt aus. Diese muss also von der gemessenen Spannung abgezogen
// werden. Die Werte 2.49 und 0.185 können verfeinert werden, in dem die
// U-I-Kennlinie des ACS712-Sensors aufgenommen wird. Benötigt wird ein
// Labornetzgerät, an dem man die Stromstärke regeln kann. Es wird eine feste
// Stromstärke eingestellt und der Spannungswert am Seriellen Monitor abgelesen.
float ACS_VOLTAGE_OFFSET = 2.49;
float ACS_GRADE          = 0.185;  // Steigung der U-I-Kennlinie

void setup() {
  pinMode(ACS_PIN, INPUT);  // Aktiviere das Lesen von Werten auf ACS_PIN
  Serial.begin(9600);       // Starte die serielle Schnittstelle
}

// Mit dieser Methode wird die durch den Strom induzierte Hallspannung im ACS712
// gemessen. Wegen des Halleffekts ist die Hallspannung proportional zur
// Stromstärke.
float get_current(int N) {
  float voltage_sum = 0;  // Variable um die gemessene Spannung aufzusummieren

  // N Messungen durchführen.
  for (int n = 0; n < N; n++) {
    float input = analogRead(ACS_PIN);       // Wert zwischen 0 und 1023 am
                                             // Analog-Pin ACS_PIN ablesen.
    float voltage = (input / 1024.0) * 5.0;  // Spannung zwischen 0 V und 5 V
                                             // aus dem abgelesen Wert
                                             // berechnen.
    voltage_sum = voltage_sum + voltage;  // Messwerte der Spannung aufaddieren,
                                          // um später einen Mittelwert zu
                                          // bilden.
  }
  // Mittelwert aus den am Pin A0 gemessenen Spannungen bilden.
  float voltage_avg = voltage_sum / N;

  // Wenn wert die Stromstärke ist, dann folgt aus einer Ausgelichsgeraden aus
  // voltage_avg = 2.49 + 0.185*current, umgestellt nach current ergibt das die
  // Formel.
  float current = (voltage_avg - ACS_VOLTAGE_OFFSET) / ACS_GRADE;

  // Gebe die berechnete Stromstärke zurück.
  return current;
}

void loop() {
  // Stromstärke messen über 10000 Messungen gemittelt.
  float current = get_current(10000);

  // Spannungswert im seriellen Monitor anzeigen.
  Serial.print("I = ");
  Serial.print(current, 2);  // Gebe die Stromstärke mit 5 Nachkommastellen aus
  Serial.println(" A");

  // Warte 500ms
  delay(500);
}