Beschreibung

Im Folgenden messen wir mithilfe eines Schallsensor den Schalldruckpegel für eine gewisse Zeit und berechnen mithilfe der sogenannten diskreten Fourier-Transformation daraus die vorhandenen Frequenzen.

Verkabelung

MF-6402171	Kabel	Arduino
A0	Gelb	A0
G	Schwarz	GND
+	Rot	5V
D0

Code

*/
#include "arduinoFFT.h"

const int SAMPLES = 128;  // SAMPLES-pt FFT. Muss eine Zweierpotenz sein.
                          // Maximal 128 für Arduino Uno.
const int SAMPLING_FREQUENCY = 2048;  // Messwerte je Sekunde. Muss mindestens
                                      // doppelt so hoch wie die höchste
                                      // erwartete Frequenz sein (Stichwort
                                      // Nyquist).

arduinoFFT FFT = arduinoFFT();

unsigned int samplingPeriod;
unsigned long microSeconds;

double vReal[SAMPLES];
double vImag[SAMPLES];

void setup() {
  Serial.begin(9600);  // Baudrate für den seriellen Monitor
  samplingPeriod = round(1000000 * (1.0 / SAMPLING_FREQUENCY));  // Periode in Mikrosekunden
  delay(1000);

  // Lese SAMPLES viele Messwerte ein
  for (int i = 0; i < SAMPLES; i++) {
    microSeconds = micros();

    vReal[i] = analogRead(0);  // Lies den Wert des Analog-Pins 0 (A0,
                               // quantisiere ihn und speicher ihn als Realteil.
    vImag[i] = 0;              // Der Imaginärteil ist immer 0.

    // Warte, bis eine Abtastperiode vergangen ist, um sicherzustellen, dass die
    // Werte in gleichmäßigen Abständen gemessen werden.
    while (micros() < (microSeconds + samplingPeriod)) {
      // Tu nichts.
    }
  }

  // Ziehe den Durchschnittswert ab, um die Frequenz 0 zu entfernen.
  // Dies ist optional und kann auch auskommentiert werden.
  double vRealAvg = 0;
  for (int i = 0; i < SAMPLES; i++) {
    vRealAvg = vRealAvg + vReal[i];
  }
  vRealAvg /= SAMPLES;
  for (int i = 0; i < SAMPLES; i++) {
    vReal[i] = vReal[i] - vRealAvg;
  }

  /*
    Führe die schnelle Fourier-Transformation (FFT) auf den samples aus.
    Hierbei werden die alten Messwerte überschrieben.
    Möchte man diese behalten, sollte man aus Speicherplatzgründen nicht den
    Arduino Uno verwenden und die Werte vor der FFT in andere Vektoren
    kopieren.
  */
  FFT.Windowing(vReal, SAMPLES, FFT_WIN_TYP_HAMMING, FFT_FORWARD);
  FFT.Compute(vReal, vImag, SAMPLES, FFT_FORWARD);

  // Schreibe die Werte auf den seriellen Monitor, um diese in eine csv-Datei
  // kopieren zu können.
  Serial.print("Frequenz;Realteil;Imaginaerteil;Betrag");
  for (int i = 0; i < SAMPLES; i++) {
    Serial.println("");
    Serial.print(1.0 * SAMPLING_FREQUENCY * i / (SAMPLES - 1.0));  // Frequenz
    Serial.print(";");
    Serial.print(vReal[i]);  // Realteil
    Serial.print(";");
    Serial.print(vImag[i]);  // Imaginaerteil
    Serial.print(";");
    Serial.print(sqrt(sq(vReal[i]) + sq(vImag[i])));  // Absolutbetrag der
                                                      // komplexen Zahl Realteil
                                                      // + i*Imaginaerteil
  }
}

void loop() {
  // Tue nichts im loop. Zum erneuten Ausführen muss der Arduino neugestartet
  // werden (roter Knopf).
}

Ablauf

Nachdem der Arduino am Computer und der Schallsensor, wie oben beschrieben, am Arduino angeschlossen ist, öffne den seriellen Monitor und stelle die im Code angegebene Baudrate ein. Es sollten bereits Werte auf dem seriellen Monitor zu sehen sein. Lösche die bisherige Ausgabe. Starte dann den Arduino durch Betätigen des roten Knopfes neu und starte dein Signal, bspw. mithilfe einer Stimmgabel oder von Kopfhörern. Im Setup ist ein delay von einer Sekunde eingebaut, damit man Zeit hat, das Signal zu starten.

Die neuen Werte, die während des Abspielens des Tons aufgenommen wurden, können nun in eine csv-Datei kopiert und anschließend mit Software wie Excel oder R visualisiert werden.

Grundsätzlich ist auch eine Visualisierung mithilfe des seriellen Plotters der Arduiono IDE möglich. Allerdings ist es in diesem nicht ohne Weiteres möglich, die x-Achse anzupassen, sodass eine Interpretation der Werte schwierig ist.

(Diskrete) Fourier-Transformation

Die diskrete (schnelle) Fourier-Transformation (“DFT” für Discrete Fourier Transform bzw. “FFT” für Fast Fourier Transform) ist ein mathematisches Werkzeug, welches ein diskretes, komplexwertiges Signal in seine Frequenzanteile aufspaltet. Intuitiv stellt die DFT das Signal durch eine Summe von Sinus- und Kosinusschwingungen variierender Frequenzen und Amplituden dar. Insbesondere hat ein reines Sinussignal genau eine Frequenz, welche nicht die Amplitude 0 hat. Der Wert dieser DFT ist wieder ein diskretes, komplexwertiges Signal. Mathematisch gesehen wird ein Vektor komplexer Zahlen auf einen weiteren Vektor komplexer Zahlen derselben Länge abgebildet. Da man jede reelle Zahl als komplexe Zahl auffassen kann, die einen Imaginärteil von 0 besitzt, ist die DFT auch für reellwertige Signale definiert. In der Praxis interessiert man sich auch meist nur für reellwertige Signale. Dass man jedoch trotzdem komplexe Zahlen verwendet, liegt daran, dass mit diesen die Darstellung relativ kompakt ist. Etwa steht in der Polarkoordinatendarstellung der Frequenzkoeffizienten der Radius für die Amplitude und der Winkel für die Phasenverschiebung des Signals. Solch eine Interpretation ist mit reellen Zahlen nicht möglich. Die DFT ist invertierbar. Das bedeutet, dass man das ursprüngliche Signal verlustfrei aus dem Frequenzspektrum rekonstruieren kann.

Aufgaben

Häufige Fragen und Probleme

Wenn ich meine selbst gemessenen Frequenzen visualisiere, sehen die Daten in der Mittel gespiegelt aus. Woran liegt das?

Das ist eine Eigenart des Betrags der (diskreten) Fourier-Transformation für reellwertige Signale. Der rechte, gespiegelte Teil kann ignoriert werden.

Mathematisch werden die Frequenzen durch komplexe Zahlen beschrieben. Warum werden sie grafisch als positive relle Zahlen dargestellt?

Kurz gesagt ist es schwer, komplexe Funktionen grafisch darzustellen. Aus folgendem Grund verliert man durch eine grafische Darstellung mit rellen Zahlen aber nur wenig Informationen: Komplexe Zahlen können in Polarkoordinaten dargestellt werden, welche aus einem Radius und einem Winkel bestehen. Der Radius beschreibt die Amplitude, welche für unsere Zwecke bedeutend ist; der Winkel einer Frequenz stellt jedoch nur die Phasenverschiebung dar. Die Frequenz eines reinen 700Hz Signals hat, bei fester Lautstärke, immer den gleichen Radius (Amplitude). Der Winkel (Phase) ist aber unterschiedlich - je nachdem, wann genau man in der Periode angefangen hat zu messen.

Warum nutzen wir komplexe Zahlen, um die frequenzen darzustellen?

Da man die Frequenzen dadurch auf eine elegante Art und Weise darstellen kann und die Sinus- und Kosinussignale somit nicht separat betrachten muss. Fourier selbst, der Namensvater der Fourier-Transformation, hat zu Beginn nur mit reellen Zahlen gearbeitet, was die Darstellung komplizierte.

Warum muss die Anzahl an Abtastwerten eine Zweierpotenz sein?

Das liegt an der verwendeten Implementierung der schnellen Fourier-Transformation. Theoretisch kann diese Operation auch auf Signale mit einer anderen Anzahl an Abtastwerten angewendet werden. In dem Fall muss aber eine andere Bibliothek verwendet werden.

Ein Sinussignal nimmt auch negative Werte an. Der Schalldruckpegel kann aber nicht negativ sein. Wie können wir ihn durch Sinus-/Kosinussignale darstellen?

Man kann eine konstante Funktion als ein Kosinussignal mit einer Frequenz von 0 auffassen. Somit beinhaltet ein reiner Ton auch eine Kosinuskurve der Frequenz 0. Im Code wird der Mittelwert des Signals abgezogen, um dieses Phänomen zu umgehen.

Quelle

Dieses Projekt, insbesondere der Code und das Schaltbild, basiert auf einem Projekt von Clyde Lettsome, siehe https://clydelettsome.com/blog/2019/12/18/my-weekend-project-audio-frequency-detector-using-an-arduino/.